home *** CD-ROM | disk | FTP | other *** search
/ Languguage OS 2 / Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO / a_utils / perl / msds-prl / ptchds19.zoo / argv_asm next >
Text File  |  1992-02-23  |  10KB  |  365 lines
  1. MS-DOS patches to perl.
  2. Apply this patch to the standard perl source, version 4, patch level 19,
  3. using "patch -p."  Do this in the root directory of the perl source
  4. distribution.
  5.  
  6. You can cat all these patches together and pipe the output to patch -p.
  7.  
  8. Len Reed
  9. Holos Software, Inc.
  10. ..!gatech!holos0!lbr
  11. holos0!lbr@gatech.edu
  12. --------------------------------------
  13. *** msdos/argv.asm.old    Sun Feb 23 08:48:16 1992
  14. --- msdos/argv.asm    Thu Nov 14 08:56:28 1991
  15. ***************
  16. *** 0 ****
  17. --- 1,347 ----
  18. + ; Invoke MKS argument handler.  If succcesful, return.
  19. + ; If unsuccessful, call MS-DOS __argv to process the command line.
  20. + 
  21. + ; Called by MS-DOS C startup code (crt0.obj in the C library).
  22. + 
  23. + ; This code used detailed knowledge of how the Microsoft C 6.0 startup
  24. + ; code works.  That source is distributed with the compiler, in
  25. + ; lib/startup and lib/startup/dos, so we're not talking about a terrible
  26. + ; guessing game here.
  27. + 
  28. + ; This code contains no MKS or Microsoft copyrighted code.
  29. + 
  30. + ; This program is free software; you can redistribute it and/or
  31. + ; modify it under the terms of the GNU General Public License
  32. + ; (version 1), as published by the Free Software Foundation, and
  33. + ; found in the file 'LICENSE' included with this distribution.
  34. + 
  35. + ; This program is distributed in the hope that it will be useful,
  36. + ; but WITHOUT ANY WARRANTY; without even the implied warrant of
  37. + ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38. + ; GNU General Public License for more details.
  39. + 
  40. + ; You must assemble this file with masm flag
  41. + ;    -dmmodel where model is one of {small, compact, medium, large}
  42. + ;
  43. + ifdef msmall
  44. +         .model    small
  45. +   ARG    equ    4
  46. + endif
  47. + ifdef mcompact
  48. +     .model  compact
  49. +   ARG    equ    4
  50. + endif
  51. + ifdef mmedium
  52. +     .model    medium
  53. +   ARG    equ    6
  54. + endif
  55. + ifdef mlarge
  56. +     .model    large
  57. +   ARG    equ    6
  58. + endif
  59. + 
  60. + ;-------------------------
  61. + 
  62. + ; The Microsoft startup code calls __setenvp and then __setargv.  Each of
  63. + ; these can return a changed stack pointer.  The routines set ___argv,
  64. + ; ___argc, and environ.
  65. + 
  66. + 
  67. + .DATA
  68. + 
  69. + If @codesize
  70. + return_adr dd ?
  71. + Else
  72. + return_adr dw ?
  73. + Endif
  74. + 
  75. + extrn __psp:word    ; our PSP segment, set by startup before __setenvp
  76. + extrn ___argc:word    ; pointer to argv[], used by startup in calling main
  77. + extrn _environ:word    ; ptr to environment ptrs, used by startup calling main
  78. + extrn STKHQQ:word    ; top of stack, defined by Microsoft C startup
  79. + extrn __osversion:word    ; MS-DOS version
  80. + 
  81. + gseg    dw    ?    ; segment of buffer passed to MKS glob
  82. + 
  83. +     Public _com_slashc
  84. + _com_slashc db    '/c', 0    ; default switch for command.com
  85. + 
  86. + .CODE
  87. + extrn ___setargv:proc    ; Microsoft globber, in C library
  88. + extrn __amsg_exit:proc    ; Microsoft stack overflow death, in C library
  89. + 
  90. + extrn _mks_init:proc    ; C code to do MKS argument analysis
  91. + extrn _mks_globber:proc    ; C code to run MKS glob.exe
  92. + 
  93. + DONT_USE equ 400h    ; stack space that must be left over after
  94. +             ; processing arguments
  95. + 
  96. + ; Define MIN_DOS_VER to be minimum version of DOS to support times 100,
  97. + ; using the -D assembler option.  If undefined, assume 2.0.
  98. + 
  99. + Ifndef MIN_DOS_VER
  100. +  MIN_DOS_VER Equ 200    ; have to at least have handle I/O, in ver 2.00
  101. + Endif
  102. + 
  103. + If MIN_DOS_VER lt 300
  104. + exec_ss    dw    ?    ; needed to support DOS 2.xx exec system call
  105. + exec_sp    dw    ?
  106. + Endif
  107. + 
  108. +     Public __setenvp
  109. + 
  110. + __setenvp Proc
  111. +     pop ax
  112. +     mov word ptr return_adr,ax
  113. + If @codesize
  114. +     pop ax
  115. +     mov word ptr return_adr + 2,ax
  116. + Endif
  117. + 
  118. +     mov ax,3000h    ; get MS-DOS version.
  119. +     int 21h
  120. +     mov __osversion,ax    ; Microsoft code we're replacing does this, too.
  121. +     mov dx,ax
  122. +     xchg dl,dh        ; version from DOS is in wrong byte order!
  123. +     cmp dx,MIN_DOS_VER    ; Approprite DOS version
  124. +     jae ver_okay
  125. +     mov bx,4        ; error message number
  126. +     jmp version_death
  127. + 
  128. + ver_okay:
  129. +     cmp al,4        ; if version 4 or beyond ignore switch char
  130. +     jae ver_4
  131. +     mov ax,3700h    ; get switch char, usually / or -
  132. +     int 21h
  133. +     mov _com_slashc,dl    ; set the switch character
  134. + 
  135. + ver_4:
  136. +     mov ax,STKHQQ    ; min SP: below this is stack overflow
  137. +     add ax,DONT_USE    ; retain some space, AX will be mks_init's SP
  138. +     cmp sp,ax        ; make sure that DONT_USE doesn't exhaust the stack
  139. +     jb too_little    ; sorry--expand the stack
  140. +     mov dx,sp
  141. +     sub dx,ax        ; DX has amount of space mks_init can play with
  142. +     mov sp,ax        ; allocate that space for mks_init
  143. +     push dx        ; tell C program how much space he gets
  144. + 
  145. +     call _mks_init    ; parse envp and args, return stack space used
  146. +                 ; return -1 for insufficient stack space
  147. +     pop dx        ; total that was available
  148. + 
  149. +     cmp ax,0FFFFh    ; was there enough space?
  150. +     je not_enough
  151. + 
  152. +     sub dx,ax        ; subtract off amount actually used
  153. +     add sp,dx        ; reduce stack by amount not used
  154. + 
  155. +     cmp ___argc,0    ; did we find the MKS arguments?
  156. +     jnz done_with_args
  157. + 
  158. +     sub sp,dx        ; reallocate the remaining space
  159. +     push dx        ; tell mks_globber how big it is
  160. +     call _mks_globber    ; try running MKS glob program
  161. +     pop dx        ; total that was available
  162. + 
  163. +     cmp ax,0FFFFh    ; was there enough space?
  164. +     je not_enough
  165. + 
  166. +     sub dx,ax        ; subtract off amount actually used
  167. +     add sp,dx        ; reduce stack by amount not used
  168. + 
  169. +     mov ax,gseg
  170. +     or ax,ax
  171. +     jz gspace_freed
  172. +     mov es,ax
  173. +     mov ah,49h        ; free the memory block used by glob
  174. +     int 21h
  175. + 
  176. + gspace_freed:
  177. +     cmp ___argc,0    ; did MKS glob program succeed?
  178. +     jnz done_with_args
  179. + 
  180. + ; Last chance, and it's a poor third choice, is to let Microsoft's globber run
  181. + ; It won't handle single quotes and thinks *.* matches abc and that * doesn't
  182. + ; match "abc.c".  It will also change the file names to upper case.  If
  183. + ; someone doesn't like that he can write a globber.
  184. + 
  185. +     call ___setargv
  186. + 
  187. + done_with_args:
  188. +     jmp return_adr
  189. + 
  190. + not_enough:
  191. +     add sp,dx        ; recover all the space that was allocated
  192. + 
  193. + too_little:
  194. +     xor ax,ax        ; message zero
  195. +     jmp    __amsg_exit    ; stack overflow message and die
  196. + __setenvp  Endp
  197. + 
  198. + ; Resolve Microsoft C's need for the following routine
  199. + 
  200. +     Public __setargv
  201. + 
  202. + __setargv  Proc
  203. +   ret            ; all was done by _setenvp
  204. + __setargv Endp
  205. + 
  206. + .DATA
  207. + 
  208. + fcb_one    db    0, 12 dup(' ')
  209. + fcb_two    db    0, 12 dup(' ')
  210. + 
  211. + gtt    db    1, ' ', '\r', '\n'    ; glob's tail is null
  212. + 
  213. + genv    dw    ?    ; segment of glob's environment
  214. + gtail    dd    gtt    ; pointer to glob's command tail
  215. + gfcb1    dd    fcb_one    ; first FCB
  216. + gfcb2    dd    fcb_two    ; second FCB
  217. + 
  218. + .CODE
  219. + 
  220. + ; Subroutine to get space for running MKS glob program.
  221. + ; Can't be using malloc() this early, so we call DOS directly.
  222. + ; Return a far pointer to the allocated 8K space, 0 for failure.
  223. + 
  224. +     Public _get_glob_space
  225. + _get_glob_space Proc
  226. +     mov ah,48h        ; MS-DOS allocate memory call
  227. +     mov bx,201h        ; 8 Kilobytes worth of paragraphs plus one paragraph
  228. +                 ; the extra paragraph is used for glob's environment
  229. +     int 21h
  230. +     jnc got_it
  231. +     sub ax,ax        ; not enough memory
  232. +     mov dx,ax
  233. +     ret
  234. + 
  235. + got_it:
  236. +     mov gseg,ax        ; save segment address
  237. +     mov dx,ax        ; return segment address
  238. +     sub ax,ax        ; offset is always zero
  239. +     ret
  240. + _get_glob_space Endp
  241. + 
  242. + ; Run the MKS glob program.
  243. + ; Arguments are standard pointer to the glob program name and far
  244. + ; pointer to the glob buffer.
  245. + 
  246. +     Public _spawn_mks_glob
  247. + 
  248. + one_dig Proc Near    ; convert to ascii and store 1 hex digit
  249. +     mov ax,dx
  250. +     and ax,0fh
  251. +     add ax,30h
  252. +     cmp ax,39h
  253. +     jbe one_dec
  254. +     add ax,7        ; change 3A to 41 ('A'), 3B to 'B' etc.
  255. + 
  256. + one_dec:
  257. +     mov es:[bx],al
  258. +     dec bx
  259. +     shr dx,cl
  260. +     ret
  261. + one_dig Endp
  262. + 
  263. + _spawn_mks_glob Proc
  264. +     push bp
  265. +     mov bp,sp
  266. +     push si
  267. +     push di
  268. + 
  269. +     mov ax,gseg        ; segment of glob buffer
  270. +     mov dx,ax        ; save for making ascii string
  271. +     add ax,200h        ; segment of where we'll put the environment
  272. +     mov genv,ax
  273. + 
  274. +     mov es,ax
  275. +     mov cx,4
  276. +     mov bx,3
  277. +     call one_dig
  278. +     call one_dig
  279. +     call one_dig
  280. +     call one_dig
  281. +     mov es:word ptr [4],3030h    ; we know glob buffer starts at para address
  282. +     mov es:word ptr [6],3030h
  283. +     mov es:byte ptr [8],0    ; terminate the string
  284. + 
  285. +     mov ax,@data        ; set ES:BX pointing to spawn parameter block
  286. +     mov es,ax
  287. +     lea bx,genv
  288. + 
  289. + If @datasize
  290. +     mov ds,[bp+ARG+2]        ; segment of program name
  291. + Endif
  292. +     mov dx,[bp+ARG]        ; offset of program name
  293. + 
  294. + If MIN_DOS_VER lt 300
  295. +     ; DOS 2.x is brain-damaged and will clobber all but CS:IP
  296. +     push ds
  297. +     mov exec_ss,ss
  298. +     mov exec_sp,sp
  299. + Endif
  300. +     mov ax,4b00h        ; spawn the glob program
  301. +     int 21h            ; we're assuming DOS 3.0+; 2.x trashes regs
  302. + If MIN_DOS_VER lt 300
  303. +     mov ss,exec_ss        ; will delay interrupts til after next instr
  304. +     mov sp,exec_sp        ; movs and pops don't change CF
  305. +     pop ds
  306. + Endif
  307. +     mov ah,0ffh            ; assume failure: note doesn't affect carry
  308. +     jc spawn_done        ; problem: return MS-DOS error code
  309. + 
  310. +     mov ah,4dh            ; get return code of glob
  311. +     int 21h
  312. + 
  313. + spawn_done:    ; return code in AX, if spawn failed, AH == 0FFh
  314. +     mov cx,ss
  315. +     mov ds,cx
  316. + 
  317. +     pop di
  318. +     pop si
  319. +     pop bp
  320. +     ret
  321. + _spawn_mks_glob Endp
  322. + 
  323. + ; Catastophe calling glob.exe.  Print message and die
  324. + 
  325. + .DATA
  326. + 
  327. + gmsg0    db 'glob: not found', 13, 10
  328. + gmsg1    db 'glob: insufficient space', 13, 10
  329. + gmsg2    db 'glob: unknown problem', 13, 10
  330. + gmsg3    db 'glob: arg list too long', 13, 10
  331. + gmsg4    db 'DOS '
  332. +     db (MIN_DOS_VER shr 8) or 30h    ; ascii major
  333. +     db '.'
  334. +     db ((MIN_DOS_VER and 0f0h) shr 4) or 30h ; ascii minor (tens)
  335. +     db (MIN_DOS_VER and 0fh) or 30h         ; ascii minor (units)
  336. +     db ' or better required', 13, 10
  337. + 
  338. + gmsg    dw gmsg0, gmsg1, gmsg2, gmsg3, gmsg4
  339. +     dw gmsg
  340. + 
  341. + .CODE
  342. + 
  343. +     Public _glob_problem
  344. + _glob_problem Proc
  345. +     push bp
  346. +     mov bp,sp
  347. +     mov bx,[bp+ARG]    ; get message index
  348. + 
  349. + version_death:
  350. +     shl bx,1        ; convert to word index
  351. +     mov dx,[bx].gmsg    ; get offset of the message
  352. +     mov cx,[bx+2].gmsg    ; get offset of next message
  353. +     sub cx,dx        ; bytes in between
  354. +     mov bx,2        ; write to stderr
  355. +     mov ah,40h
  356. +     int 21h
  357. + 
  358. +     mov ax,4c01h    ; terminte with return code 1
  359. +     int 21h
  360. +     ; no return
  361. + _glob_problem Endp
  362. + 
  363. + 
  364. + End
  365.